home *** CD-ROM | disk | FTP | other *** search
/ The X-Philes (2nd Revision) / The X-Philes Number 1 (1995).iso / xphiles / hp48hor1 / moon2.src < prev    next >
Text File  |  1990-10-18  |  2KB  |  64 lines
  1. %%HP: T(3)A(D)F(.);
  2. @ MOON2 by Dan Gerson;
  3. @ graphics from MOON by Craig Finseth.
  4. DIR
  5.   MPHASE
  6.     \<< RCLF -31 SF DEG ERASE { # 0h # 0h } PVIEW { # 40h # 1Ch }
  7.       # 1Ah 0 360 ARC 26 28 MFRAC SWAP DROP MPLOT MFINI 7 FREEZE STOF
  8.     \>>
  9.   MTIME
  10.     \<< MFRAC \-> PCT X
  11.       \<< X 29.53058868 * DUP 'X' STO IP "d " + X FP 24 * IP + "h " + X FP
  12.         1440 * 60 MOD IP + "m (" + PCT 100 * 0 RND + "%)" +
  13.       \>>
  14.     \>>
  15.   MFRAC
  16.     \<< RCLF 0 0 0 0 0 0 JDAT 2444239 - \-> FLGS M ML MM EV AE A3 day
  17.       \<< RAD day .985647332099 * 360 MOD -3.762863 + 360 MOD D\->R 'M' STO
  18.         'E=.016718*SIN(E)+M' 'E' M ROOT 2 / TAN 1.01686011182 * ATAN R\->D 2 *
  19.         282.596403 + 360 MOD 'E' STO 13.1763966 day * 64.975464 + 360 MOD DUP
  20.         'ML' STO .1114041 day * - 349.383063 - 360 MOD 'MM' STO ML E - 2 * MM
  21.         - D\->R SIN 1.2739 * 'EV' STO M SIN DUP .1858 * 'AE' STO .37 * 'A3' STO
  22.         MM EV + AE - A3 - DUP D\->R SIN 6.2886 * SWAP 2 * D\->R SIN .214 * SWAP
  23.         EV + ML + AE - + DUP E - 2 * D\->R SIN .6583 * + E - DUP D\->R COS NEG
  24.         1 + 2 / 'Illuminated' \->TAG SWAP 360 MOD 360 / 'Age' \->TAG FLGS STOF
  25.       \>>
  26.     \>>
  27.   JDAT
  28.     \<< 1.01198 DATE DDAYS 2444240 + TIME HMS\-> TMZN + 24 / +
  29.     \>>
  30.   MPLOT
  31.     \<< \-> RA MI F
  32.       \<<
  33.         IF F .5 <
  34.         THEN F 360 * COS RA * RA
  35.         ELSE RA NEG F .5 - 360 * COS RA *
  36.         END \-> L R
  37.         \<< 1 0
  38.           FOR x x ACOS SIN DUP MI x RA * + L R MLINE MI x RA * - L R MLINE RA
  39.             INV NEG
  40.           STEP
  41.         \>>
  42.       \>>
  43.     \>>
  44.   MLINE
  45.     \<< \-> SC LI L R
  46.       \<< SC L * 64 + R\->B LI R\->B 2 \->LIST SC R * 64 + R\->B LI R\->B 2
  47.         \->LIST LINE
  48.       \>>
  49.     \>>
  50.   MFINI @ Adds "stars" (just a few random fixed blobs)
  51.     \<< { # Ah # Ah } PIXON
  52.         { # 6Eh # Fh } PIXON
  53.         { # 64h # 32h } PIXON
  54.         { # 1Eh # 29h } PIXON
  55.         { # 1Fh # 29h } PIXON PICT NEG
  56.     \>>
  57.   SLOFLIP
  58.     \<< 0 63
  59.       FOR l # 0h l R\->B 2 \->LIST # 82h l R\->B 2 \->LIST TLINE
  60.       NEXT
  61.     \>>
  62.   E 109.444275789
  63. END
  64.